MLC:
#FNCT MAIN
#ARRY @A .40
%E=.0
%B=.1
%D=.1
%Z=.0
%L=.0
#FRUN MENU
#FEND

#FNCT MENU
#CLRS
#RECT .0 .0 .95 .63 .2 .5
#RECT .1 .1 .94 .62 .0 .5
#RECT .2 .2 .93 .61 .1 .5
#RECT .3 .3 .92 .60 .0 .3
#TEXT .27 .12 "N E M O" .2
#TEXT .25 .10 "N E M O" .0
#TEXT .35 .25 "BY SAMY" .0
#IIFF %B!.1
#TEXT .25 .35 "NOUVEAU JEU" .1
#IIFF %B!.2
#TEXT .25 .42 "OPTION" .1
#IIFF %B!.3
#TEXT .25 .49 "QUITTER" .1
#IIFF %B=.1
#TEXT .25 .35 "#NOUVEAU JEU" .1
#IIFF %B=.2
#TEXT .25 .42 "#OPTION" .1
#IIFF %B=.3
#TEXT .25 .49 "#QUITTER" .1
#DRAW
#WAIT .500
#WKEY %A
#IIFF %A=.0
#FGOB
#IIFF %A!.25&%A!.34&%A!.95
#FGOB
#IIFF %A=.25
%B=%B-.1
#IIFF %A=.34
%B=%B+.1
#IIFF %B=.0
%B=.3
#IIFF %B=.4
%B=.1
%C=%D
#IIFF %B=.1&%A=.95
#FRUN INI
#IIFF %B=.2&%A=.95
#FRUN OPT
#IIFF %B=.3&%A=.95
#HALT
#FGOB
#FEND

#FNCT OPT
#RECT .4 .32 .91 .59 .3 .3
#IIFF %C!.1
#TEXT .25 .35 "FACILE" .1
#IIFF %C!.2
#TEXT .25 .41 "DIFFICILE" .1
#IIFF %C!.3
#TEXT .25 .47 "AIDE" .1
#IIFF %C!.4
#TEXT .25 .53 "RETOUR" .1
#IIFF %C=.1
#TEXT .25 .35 "#FACILE" .1
#IIFF %C=.2
#TEXT .25 .41 "#DIFFICILE" .1
#IIFF %C=.3
#TEXT .25 .47 "#AIDE" .1
#IIFF %C=.4
#TEXT .25 .53 "#RETOUR" .1
#DRAW
#WAIT .500
#WKEY %A
#IIFF %A=.0
#FGOB
#IIFF %A!.25&%A!.34&%A!.95
#FGOB
#IIFF %A=.25
%C=%C-.1
#IIFF %A=.34
%C=%C+.1
#IIFF %C=.0
%C=.4
#IIFF %C=.5
%C=.1
#IIFF %C<.3&%A=.95
%D=%C
#IIFF %C=.3&%A=.95
#FRUN AIDE
#IIFF %A=.95
#FRUN MENU
#FGOB

#FNCT AIDE
#RECT .4 .32 .91 .57 .3 .3
#TEXT .5 .33 "BUT DU JEU:SELECTIONNE" .1
#TEXT .5 .39 "DEUX CARTES AVEC LES" .1
#TEXT .5 .45 "FLECHES ET EXE AFIN" .1
#TEXT .5 .51 "DE TROUVER LES PAIRES," .1
#DRAW
#WAIT .1000
#PAUS
#RECT .4 .32 .91 .57 .3 .3
#TEXT .5 .33 "LE MODE DIFFICILE" .1
#TEXT .5 .39 "INVERSE LES CARTES" .1
#TEXT .5 .45 "RETOURNEES SI CE" .1
#TEXT .5 .51 "N'EST PAS UNE PAIRE." .1
#WAIT .500
#DRAW
#PAUS
#FEND

#FNCT DISTR
#RNDM .0 .39 %F
#IIFF @A(%F)!.0
#FGOB
%E=%E+.1
%G=%E
#IIFF %E>.20
%G=%E-.20
@A(%F)=%G
#IIFF %E<.40
#FGOB
#RECT .4 .4 .91 .59 .3 .3
%Z=.0
%Y=.0
#FRUN DESSI
#FEND

#FNCT INI
@A(%Z)=.0
%Z=.1+%Z
#IIFF %Z!.40
#FGOB
#FRUN DISTR
#FEND

#FNCT DESSI
#RECT %Z*.9+.5 %Y*.11+.5 %Z*.9+.11 %Y*.11+.13 .0 .5
#LINE %Z*.9+.5 %Y*.11+.5 %Z*.9+.10 %Y*.11+.10 .0
#LINE %Z*.9+.5 %Y*.11+.8 %Z*.9+.10 %Y*.11+.13 .0
%Z=.1+%Z
#IIFF %Z=.8
%Y=%Y+.1
#IIFF %Z=.8
%Z=.0
#IIFF %Y!.6
#FGOB
%Z=.0
%Y=.0
%X=.0
#STOP
#FRUN JEU
#FEND

#FNCT JEU
#PIXT %Z*.9+.6 %Y*.11+.7 %V
#IIFF %V!.0
#RECT %Z*.9+.4 %Y*.11+.4 %Z*.9+.12 %Y*.11+.14 .1 .4
#DRAW
#WKEY %A
#IIFF %A!.25&%A!.34&%A!.95&%A!.24&%A!.26
#FGOB
#RECT %Z*.9+.4 %Y*.11+.4 %Z*.9+.12 %Y*.11+.14 .3 .4
#WAIT .250
#IIFF %A=.24
%Z=%Z-.1
#IIFF %A=.26
%Z=%Z+.1
#IIFF %A=.25
%Y=%Y-.1
#IIFF %A=.34
%Y=%Y+.1
#IIFF %Y<.0
%Y=.4
#IIFF %Z<.0
%Z=.7
#IIFF %Y>.4
%Y=.0
#IIFF %Z>.7
%Z=.0
#IIFF %A!.95
#FGOB
#IIFF %X=.0
%M=%Y
#IIFF %X=.0
%N=%Z
#IIFF %X=.1
%O=%Y
#IIFF %X=.1
%P=%Z
#IIFF %X=.1&%M=%O&%N=%P
#FGOB
#IIFF %A=.95&@A(.8*%Y+%Z)=.0
#FGOB
#IIFF %A=.95
#FRUN CARTE
%X=%X+.1
#IIFF %X=.2
#FRUN VERIF
#IIFF %L!.20
#FGOB
#CLRS
#IIFF %C=.2
#TEXT .25 .24 "DOUBLE" .1
#TEXT .13 .34 "FELICITATION!" .1
#IIFF %C=.2
#TEXT .27 .21 "DOUBLE" .3
#TEXT .15 .31 "FELICITATION!" .3
#DRAW
#PAUS
#HALT
#FEND

#FNCT VERIF
%U=.0
%X=.0
#WKEY %V
#IIFF %V=.0
#FGOB
#WAIT .250
#IIFF @A(.8*%M+%N)!@A(.8*%O+%P)
%U=.1
#IIFF %U=.1
#RCLP
#IIFF %U=.1&%C=.2
%U=.2
%A=@A(.8*%M+%N)
#IIFF %U=.2
@A(.8*%M+%N)=@A(.8*%O+%P)
#IIFF %U=.2
@A(.8*%O+%P)=%A
#IIFF %U!.0
#FEND
#RECT %N*.9+.5 %M*.11+.5 %N*.9+.11 %M*.11+.13 .3 .3
#RECT %P*.9+.5 %O*.11+.5 %P*.9+.11 %O*.11+.13 .3 .3
#DRAW
#STOP
@A(.8*%M+%N)=.0
@A(.8*%O+%P)=.0
%L=%L+.1
#FEND

#FNCT CARTE
%W=.8*%Y+%Z
%W=@A(%W)
%Q=.0
#FRUN RETO
#IIFF %W=.1
#FRUN A
#IIFF %W=.2
#FRUN B
#IIFF %W=.3
#FRUN C
#IIFF %W=.4
#FRUN D
#IIFF %W=.5
#FRUN E
#IIFF %W=.6
#FRUN F
#IIFF %W=.7
#FRUN G
#IIFF %W=.8
#FRUN H
#IIFF %W=.9
#FRUN I
#IIFF %W=.10
#FRUN J
#IIFF %W=.11
#FRUN K
#IIFF %W=.12
#FRUN L
#IIFF %W=.13
#FRUN M
#IIFF %W=.14
#FRUN N
#IIFF %W=.15
#FRUN O
#IIFF %W=.16
#FRUN P
#IIFF %W=.17
#FRUN Q
#IIFF %W=.18
#FRUN R
#IIFF %W=.19
#FRUN S
#DRAW
#FEND

#FNCT RETO
%Q=%Q+.1
#RECT %Z*.9+.5 %Y*.11+.5 %Z*.9+.11 %Y*.11+.13 .3 .3
#RECT %Z*.9+.5+%Q %Y*.11+.5 %Z*.9+.11-%Q %Y*.11+.13 .0 .5
#DRAW
#WAIT .300
#IIFF %Q!.6
#FGOB
#FEND

#FNCT A
#RECT %Z*.9+.7 %Y*.11+.7 %Z*.9+.9 %Y*.11+.8 .0 .0
#RECT %Z*.9+.7 %Y*.11+.11 %Z*.9+.9 %Y*.11+.10 .0 .0
#LINE %Z*.9+.8 %Y*.11+.10 %Z*.9+.8 %Y*.11+.8 .4
#FEND

#FNCT B
#LINE %Z*.9+.7 %Y*.11+.7 %Z*.9+.9 %Y*.11+.7 .0
#LINE %Z*.9+.7 %Y*.11+.8 %Z*.9+.9 %Y*.11+.10 .0
#LINE %Z*.9+.7 %Y*.11+.9 %Z*.9+.7 %Y*.11+.10 .0
#LINE %Z*.9+.7 %Y*.11+.11 %Z*.9+.9 %Y*.11+.11 .0
#FEND

#FNCT C
#LINE %Z*.9+.7 %Y*.11+.7 %Z*.9+.9 %Y*.11+.7 .0
#LINE %Z*.9+.7 %Y*.11+.9 %Z*.9+.9 %Y*.11+.9 .0
#LINE %Z*.9+.7 %Y*.11+.11 %Z*.9+.9 %Y*.11+.11 .0
#FEND

#FNCT D
#LINE %Z*.9+.7 %Y*.11+.7 %Z*.9+.7 %Y*.11+.11 .0
#LINE %Z*.9+.9 %Y*.11+.7 %Z*.9+.9 %Y*.11+.11 .0
#FEND

#FNCT E
#LINE %Z*.9+.7 %Y*.11+.7 %Z*.9+.9 %Y*.11+.7 .0
#LINE %Z*.9+.7 %Y*.11+.9 %Z*.9+.9 %Y*.11+.9 .0
#PIXL %Z*.9+.7 %Y*.11+.10 .0
#PIXL %Z*.9+.9 %Y*.11+.10 .0
#LINE %Z*.9+.7 %Y*.11+.11 %Z*.9+.9 %Y*.11+.11 .0
#FEND

#FNCT F
#LINE %Z*.9+.7 %Y*.11+.7 %Z*.9+.9 %Y*.11+.7 .0
#LINE %Z*.9+.7 %Y*.11+.8 %Z*.9+.9 %Y*.11+.8 .0
#LINE %Z*.9+.7 %Y*.11+.10 %Z*.9+.9 %Y*.11+.10 .0
#LINE %Z*.9+.7 %Y*.11+.11 %Z*.9+.9 %Y*.11+.11 .0
#FEND

#FNCT G
#PIXL %Z*.9+.8 %Y*.11+.7 .0
#LINE %Z*.9+.7 %Y*.11+.8 %Z*.9+.9 %Y*.11+.8 .0
#LINE %Z*.9+.7 %Y*.11+.10 %Z*.9+.9 %Y*.11+.10 .0
#PIXL %Z*.9+.8 %Y*.11+.11 .0
#FEND

#FNCT H
#LINE %Z*.9+.8 %Y*.11+.7 %Z*.9+.8 %Y*.11+.11 .0
#LINE %Z*.9+.7 %Y*.11+.8 %Z*.9+.9 %Y*.11+.8 .0
#LINE %Z*.9+.7 %Y*.11+.10 %Z*.9+.9 %Y*.11+.10 .0
#FEND

#FNCT I
#LINE %Z*.9+.7 %Y*.11+.7 %Z*.9+.7 %Y*.11+.9 .0
#PIXL %Z*.9+.8 %Y*.11+.9 .0
#LINE %Z*.9+.9 %Y*.11+.9 %Z*.9+.9 %Y*.11+.11 .0
#FEND

#FNCT J
#LINE %Z*.9+.8 %Y*.11+.7 %Z*.9+.8 %Y*.11+.11 .0
#LINE %Z*.9+.7 %Y*.11+.8 %Z*.9+.9 %Y*.11+.8 .0
#FEND

#FNCT K
#LINE %Z*.9+.9 %Y*.11+.7 %Z*.9+.9 %Y*.11+.9 .0
#PIXL %Z*.9+.8 %Y*.11+.9 .0
#LINE %Z*.9+.7 %Y*.11+.9 %Z*.9+.7 %Y*.11+.11 .0
#FEND

#FNCT L
#LINE %Z*.9+.7 %Y*.11+.7 %Z*.9+.9 %Y*.11+.7 .0
#LINE %Z*.9+.7 %Y*.11+.9 %Z*.9+.9 %Y*.11+.9 .0
#LINE %Z*.9+.7 %Y*.11+.11 %Z*.9+.9 %Y*.11+.11 .0
#LINE %Z*.9+.8 %Y*.11+.8 %Z*.9+.8 %Y*.11+.10 .4
#FEND

#FNCT M
#LINE %Z*.9+.7 %Y*.11+.7 %Z*.9+.9 %Y*.11+.7 .0
#LINE %Z*.9+.7 %Y*.11+.9 %Z*.9+.9 %Y*.11+.9 .0
#LINE %Z*.9+.7 %Y*.11+.11 %Z*.9+.9 %Y*.11+.11 .0
#LINE %Z*.9+.8 %Y*.11+.8 %Z*.9+.8 %Y*.11+.10 .0
#FEND

#FNCT N
#LINE %Z*.9+.7 %Y*.11+.7 %Z*.9+.9 %Y*.11+.7 .0
#PIXL %Z*.9+.8 %Y*.11+.8 .0
#PIXL %Z*.9+.8 %Y*.11+.10 .0
#LINE %Z*.9+.7 %Y*.11+.11 %Z*.9+.9 %Y*.11+.11 .0
#FEND

#FNCT O
#LINE %Z*.9+.7 %Y*.11+.8 %Z*.9+.9 %Y*.11+.8 .0
#LINE %Z*.9+.7 %Y*.11+.10 %Z*.9+.9 %Y*.11+.10 .0
#LINE %Z*.9+.8 %Y*.11+.7 %Z*.9+.8 %Y*.11+.11 .4
#FEND

#FNCT P
#LINE %Z*.9+.7 %Y*.11+.7 %Z*.9+.7 %Y*.11+.11 .0
#LINE %Z*.9+.9 %Y*.11+.7 %Z*.9+.9 %Y*.11+.11 .0
#PIXL %Z*.9+.8 %Y*.11+.8 .0
#PIXL %Z*.9+.8 %Y*.11+.10 .0
#FEND

#FNCT Q
#LINE %Z*.9+.7 %Y*.11+.7 %Z*.9+.7 %Y*.11+.11 .0
#LINE %Z*.9+.9 %Y*.11+.7 %Z*.9+.9 %Y*.11+.11 .0
#LINE %Z*.9+.8 %Y*.11+.8 %Z*.9+.8 %Y*.11+.10 .0
#FEND

#FNCT R
#RECT %Z*.9+.6 %Y*.11+.6 %Z*.9+.10 %Y*.11+.12 .3 .0
#FEND

#FNCT S
#RECT %Z*.9+.7 %Y*.11+.7 %Z*.9+.9 %Y*.11+.11 .0 .3
#FEND